Libraries
Libraries extend the Processing Application beyond graphic and image. By adding libraries to your sketches you can enable audio, video, communication, and in terms of 3D printing, export your files as STL documents. The following libraries are useful for 3D Printing:- opengl
- ModelBuilder
- controlP5
- toxiclibs
- shapes3D
Installing
- Open Processing, then open Preferences
- Make a note of where your sketchbook lives:
- Download the latest version of your library
- Navigate to your Sketchbook location
- If you do not already have a libraries folder in the directory, create one.
- Move the library into the libraries folder.
- If Processing is open, close it and restart the application.
OpenGL
The OpenGL library, which is included with the Processing software, provides support for exporting OpenGL accelerated sketches. It utilizes the JOGL library.
import processing.opengl.*;
void setup(){
size(100,100,OPENGL);
}Modelbuilder
ModelBuilder focuses on computational 3D modelling for digital fabrication. Once a model is built, ModelBuilder provides convenient methods to center it around origin, scale it to given dimensions and output it to STL format. The library was created by MARIUS WATZ, an artist working with code to explore virtual spaces defined by rule-based systems. He currently splits his time between Brooklyn, New York and Oslo, Norway.- Open Processing, then open Preferences
- Make a note of where your sketchbook lives:
- Download the latest version of ModelBuilder and Unlekker
- Navigate to your Sketchbook location
- If you do not already have a libraries folder in the directory, create one.
- Move ModelBuilder and Unlekker into the libraries folder.
- If Processing is open, close it and restart the application.
- Paste the following into the sketch
import unlekker.util.*; import unlekker.modelbuilder.*; import ec.util.*; // unlekkerLib - Marius Watz, workshop.evolutionzone.com // Example showing how to write geometry to a STL file. import unlekker.data.*; void setup() { size(400,400, P3D); noLoop(); } void draw() { background(100); // Initialize STL output beginRaw("unlekker.data.STL","myFile.stl"); translate(width/2,height/2,-width/2); sphere(width/2); // End STL output endRaw(); } - Test the sketch, you should end up with an stl file in your sketch folder.
Toxiclib
toxiclibs is an independent, open source library collection for computational design tasks with Java & Processing developed by Karsten toxi Schmidt. The design philosophy of this library is based on a polymorphic software architecture and the strict separation of abstract models and their actual representations. A model of a sphere is just a mathematical concept, but it can also be treated as a generic 3D form and can be used and manipulated independently from its representation, e.g. as a mesh of triangle faces. The core library covers: 2D/3D vector maths, primitive forms, point clouds, voronoi maps, spatial trees, matrix operations, quaternions, splines, terrains, meshes with support for perforation, subdivision and smoothing, implicit surfaces, intersections between primitives, and import/export of geometry data as STL/OBJ.To create Mesh Shapes, use toxiclibscore:mesh
Using FileOutputStream
import toxi.geom.*;
import toxi.geom.mesh.*;
import toxi.processing.*;
TriangleMesh mesh;
ToxiclibsSupport gfx;
void setup() {
size(400, 400, P3D);
gfx=new ToxiclibsSupport(this);
}
void draw() {
// define a rounded cube using the SuperEllipsoid surface function
SurfaceFunction f=new SuperEllipsoid(width/(mouseX+10), height/(mouseY+10));
SurfaceMeshBuilder b = new SurfaceMeshBuilder(f);
// execute the mesh (resolution=80, radius=100)
mesh = (TriangleMesh)b.createMesh(null, 30, 60);
background(128);
fill(255);
stroke(0);
lights();
translate(width / 2, height / 2, 0);
rotateX(mouseY * 0.01f);
rotateY(mouseX * 0.01f);
gfx.mesh(mesh);
}
void keyPressed() {
if (key=='e') {
try {
String fileID="shape-"+(System.currentTimeMillis()/1000);
FileOutputStream fs;
fs=new FileOutputStream(sketchPath(fileID+".stl"));
mesh.saveAsSTL(fs);
}
catch(Exception e) {
e.printStackTrace();
}
}
}
Using Vec3D
import processing.opengl.*;
import toxi.geom.*;
import toxi.geom.mesh.*;
import toxi.processing.*;
TriangleMesh mesh = new TriangleMesh();
ToxiclibsSupport gfx;
int i=0;
void setup() {
size(400,400,OPENGL);
gfx=new ToxiclibsSupport(this);
}
void draw() {
background(51);
lights();
translate(width / 2, height / 2, 0);
rotateX(mouseY * 0.01f);
noStroke();
Vec3D BOX_SIZE = new Vec3D(mouseX/2,mouseY/2,mouseX/2);
TriangleMesh b=(TriangleMesh)new AABB(new Vec3D(), BOX_SIZE).toMesh();
gfx.mesh(b);
}
void keyPressed() {
i++;
if (key == 's') {
mesh.saveAsSTL(sketchPath("cube"+i+".stl"));
}
}
Spherical Harmonics
/** *SphericalHarmonicsMeshBuilder demonstrates how to use the SurfaceMeshBuilder class in conjunction with a spherical harmonics function to dynamically create a variety of organic looking forms. The function is described in detail on Paul Bourke's website. Included is also a re-usable function for displaying a generic TriangleMesh instance using normal mapping. the display of surface normals useful for debug purposes. r: randomize spherical harmonics w: toggle wireframe on/off n: toggle normal vector display on/off s: save current mesh as STL file * Copyright (c) 2010 Karsten Schmidt */ import processing.opengl.*; import toxi.math.waves.*; import toxi.geom.*; import toxi.geom.mesh.*; TriangleMesh mesh = new TriangleMesh(); boolean isWireFrame; boolean showNormals; boolean doSave; int i=0; Matrix4x4 normalMap = new Matrix4x4().translateSelf(128,128,128).scaleSelf(127); void setup() { size(400,400, OPENGL); randomizeMesh(); } void draw() { background(0); translate(width / 2, height / 2, 0); rotateX(mouseY * 0.01f); rotateY(mouseX * 0.01f); lights(); shininess(16); directionalLight(255,255,255,0,-1,1); specular(255); drawAxes(400); if (isWireFrame) { noFill(); stroke(255); } else { fill(255); noStroke(); } drawMesh(g, mesh, !isWireFrame, showNormals); } void drawAxes(float l) { stroke(255, 0, 0); line(0, 0, 0, l, 0, 0); stroke(0, 255, 0); line(0, 0, 0, 0, l, 0); stroke(0, 0, 255); line(0, 0, 0, 0, 0, l); } void drawMesh(PGraphics gfx, TriangleMesh mesh, boolean vertexNormals, boolean showNormals) { gfx.beginShape(PConstants.TRIANGLES); AABB bounds=mesh.getBoundingBox(); Vec3D min=bounds.getMin(); Vec3D max=bounds.getMax(); if (vertexNormals) { for (Iterator i=mesh.faces.iterator(); i.hasNext();) { Face f=(Face)i.next(); Vec3D n = normalMap.applyTo(f.a.normal); gfx.fill(n.x, n.y, n.z); gfx.normal(f.a.normal.x, f.a.normal.y, f.a.normal.z); gfx.vertex(f.a.x, f.a.y, f.a.z); n = normalMap.applyTo(f.b.normal); gfx.fill(n.x, n.y, n.z); gfx.normal(f.b.normal.x, f.b.normal.y, f.b.normal.z); gfx.vertex(f.b.x, f.b.y, f.b.z); n = normalMap.applyTo(f.c.normal); gfx.fill(n.x, n.y, n.z); gfx.normal(f.c.normal.x, f.c.normal.y, f.c.normal.z); gfx.vertex(f.c.x, f.c.y, f.c.z); } } else { for (Iterator i=mesh.faces.iterator(); i.hasNext();) { Face f=(Face)i.next(); gfx.normal(f.normal.x, f.normal.y, f.normal.z); gfx.vertex(f.a.x, f.a.y, f.a.z); gfx.vertex(f.b.x, f.b.y, f.b.z); gfx.vertex(f.c.x, f.c.y, f.c.z); } } gfx.endShape(); if (showNormals) { if (vertexNormals) { for (Iterator i=mesh.vertices.values().iterator(); i.hasNext();) { Vertex v=(Vertex)i.next(); Vec3D w = v.add(v.normal.scale(10)); Vec3D n = v.normal.scale(127); gfx.stroke(n.x + 128, n.y + 128, n.z + 128); gfx.line(v.x, v.y, v.z, w.x, w.y, w.z); } } else { for (Iterator i=mesh.faces.iterator(); i.hasNext();) { Face f=(Face)i.next(); Vec3D c = f.a.add(f.b).addSelf(f.c).scaleSelf(1f / 3); Vec3D d = c.add(f.normal.scale(20)); Vec3D n = f.normal.scale(127); gfx.stroke(n.x + 128, n.y + 128, n.z + 128); gfx.line(c.x, c.y, c.z, d.x, d.y, d.z); } } } } void keyPressed() { if (key == 'r') { randomizeMesh(); } if (key == 'w') { isWireFrame = !isWireFrame; } if (key == 'n') { showNormals = !showNormals; } if (key == 's') { mesh.saveAsSTL(sketchPath("shape-"+i+".stl")); } } void randomizeMesh() { float[] m=new float[8]; for(int i=0; i<8; i++) { m[i]=(int)random(9); } SurfaceMeshBuilder b = new SurfaceMeshBuilder(new SphericalHarmonics(m)); mesh = (TriangleMesh)b.createMesh(null,80, 40); }
controlP5
controlP5 by Andreas Schlegel allows you to use custom GUI elements with the ability to show/hide and move while the program is running./** * ControlP5basics
* The following example demonstrates the basic use of controlP5.
* After initializing controlP5 you can add controllers to controlP5. * Here we use three numberboxes, one slider and one textfield. * The numberbox with name numberboxC will trigger function numberboxC() * in the example below. Whenever controlP5 detects a function in your * sketch that corresponds to the name of a controller, it will forward * an event to that function. Any event triggered by a controller * will be forwarded to function controlEvent in your sketch.
* related examples ControlP5numberbox, ControlP5slider, ControlP5textfield
* by Andreas Schlegel 2010
* */ import controlP5.*; ControlP5 controlP5; public int myColorRect = 200; public int myColorBackground = 100; void setup() { size(400,400); frameRate(25); controlP5 = new ControlP5(this); controlP5.addNumberbox("numberboxA",myColorRect,100,140,100,14).setId(1); controlP5.addNumberbox("numberboxB",myColorBackground,100,180,100,14).setId(2); controlP5.addNumberbox("numberboxC",0,100,220,100,14).setId(3); controlP5.addSlider("sliderA",100,200,100,100,260,100,14).setId(4); controlP5.addTextfield("textA",100,290,100,20).setId(5); controlP5.controller("numberboxA").setMax(255); controlP5.controller("numberboxA").setMin(0); } void draw() { background(myColorBackground); fill(myColorRect); rect(0,0,width,100); } public void numberboxC(int theValue) { println("### got an event from numberboxC : "+theValue); } // a slider event will change the value of textfield textA public void sliderA(int theValue) { ((Textfield)controlP5.controller("textA")).setValue(""+theValue); } // for every change in textfield textA, this function will be called public void textA(String theValue) { println("### got an event from textA : "+theValue); } public void controlEvent(ControlEvent theEvent) { println("got a control event from controller with id "+theEvent.controller().id()); switch(theEvent.controller().id()) { case(1): // numberboxA myColorRect = (int)(theEvent.controller().value()); break; case(2): // numberboxB myColorBackground = (int)(theEvent.controller().value()); break; }
shapes3D
3D shapes for processing is useful for any one wishing to do some 3D graphics/games programming in P3D or OPENGL modes. It not only provides a number of 3D shapes but enables simple creation of a 3D terrain and user controllable camera that can traverse over the terrain.Some of the example files are dependent on Peasycam and guicomponents
For this example, you must have ModelBuilder:
import shapes3d.utils.*;
import shapes3d.*;
import processing.opengl.*;
import unlekker.util.*;
import unlekker.modelbuilder.*;
import ec.util.*;
import unlekker.data.*;
int i=0;
Box box;
Ellipsoid sphere;
float a;
void setup() {
size(200, 200, OPENGL);
cursor(CROSS);
}
void draw() {
float size=map(mouseX, 0, width, 10, width/8);
//controls slices (north to south)
int slices=10;
//controls segments (east to west)
int segments=(int)map(mouseY, 0, height, 10, height/2);
box=new Box(this, size, size, size);
box.moveTo(0, size, 0);
box.fill(255);
box.stroke(color(64, 0, 64));
box.strokeWeight(1.2);
box.drawMode(Shape3D.SOLID | Shape3D.WIRE);
sphere=new Ellipsoid(this, slices, segments);
sphere.setRadius(size);
sphere.moveTo(0, -size/4, 0);
sphere.fill(255);
sphere.stroke(color(64, 0, 64));
sphere.strokeWeight(1.2);
sphere.drawMode(Shape3D.SOLID | Shape3D.WIRE);
background(128);
pushMatrix();
camera(70 * sin(a), 10, 70 * cos(a), 0, 0, 0, 0, 1, 0);
ambientLight(200, 200, 200);
directionalLight(128, 128, 128, -1, 0, -1);
box.draw();
sphere.draw();
popMatrix();
a += 0.002;
}
void keyPressed() {
if (key == 'e') {
i++;
beginRaw("unlekker.data.STL", "shape"+i+".stl");
pushMatrix();
camera(70 * sin(a), 10, 70 * cos(a), 0, 0, 0, 0, 1, 0);
ambientLight(200, 200, 200);
directionalLight(128, 128, 128, -1, 0, -1);
box.draw();
sphere.draw();
popMatrix();
endRaw();
}
}